Fasciculus:Euclidian and non euclidian geometry.png

E Vicipaedia
Jump to navigation Jump to search

Sua resolutio(4 000 × 1 500 elementa imaginalia, magnitudo fasciculi: 128 chiliocteti, typus MIME: image/png)

Hic fasciculus apud Vicimedia Communia iacet; in aliis inceptis adhiberi potest. Contenta paginae descriptionis fasciculi subter monstrantur.

Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate

  1. euclidian
  2. elliptical and
  3. hyperbolic geometry

To be exact, the hyperbolic surface was approximated using a chunk of the "inside" of a torus - this may not be perfectly accurate, but apparently it "looks right" in this illustration. :-)

Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped and "numbered" using a graphics software package.


  /*
  ====================================================================
  Surfaces demonstrating euclidian, elliptical and hyperbolic geometry
  --------------------------------------------------------------------
  Created by Søren Peo Pedersen - see my user page at
  http://da.wikipedia.org/wiki/Bruger:Peo
  ====================================================================
  */
  
  // Macro for texture with background pattern, lines, and point "marker"
  #macro SurfaceDrawing (
    Point,        // Position vector: Location of white point
    RefLineMove,  // Transformation: Where to place the yellow reference line
    Lines         // Object that renders the blue line(s)
    )
  
      #local BasePattern=pigment {  // The underlying, dark grey checkerboard pattern
          checker
          color rgb 0.4
          color rgb 0.6
          scale <1,1000,1>
          }
  
      #local SP1 = pigment {    // Checkerboard pattern with yellow "reference line" added
          object {box {<-.07,-10,-10>,<.07,10,10> transform{RefLineMove}}
              pigment {BasePattern}
              pigment {color rgb <1,.8,.3>}
              }
          }    
  
      #local SP2 = pigment {    // Checkerborad + yellow line with user-defined (blue) lines added
          object {Lines
              pigment {SP1}
              pigment {color rgb <.6,.8,1>}
              }
          }    
  
      #local SP3 = pigment {    // Checkerboard + lines with whit point "marker" added
          object {
              sphere { Point, .2 }
              pigment {SP2}
              pigment {color rgb 1}
              }
          }
  
      pigment {   // Definition of pigment, confined to a box slightly smaller than the "blocks"
          boxed   // to make the lines and point only appear on the top of the blocks
          pigment_map {
              [0.0000 BasePattern scale .5 translate <0,-1,0>]
              [0.0001 BasePattern scale .5 translate <0,-1,0>]
              [0.0001 SP3 scale .5 translate <0,-1,0>]
              [1.0000 SP3 scale .5 translate <0,-1,0>]
              }
          scale <2,2,2> translate <0,2,0>
          }          
      finish {ambient .7 diffuse .3}
  #end  // End of macro
  
  plane {<0,1,0>,0      // White "tabletop" to receive shadows of the blocks (helps visualisation)
      pigment {color rgb 1}
      finish {ambient .8 diffuse .5}
      }
  
  box {<-2,0,-2>,<2,2,2>  // Demonstrating euclidean geometry
      texture {
          SurfaceDrawing(<-.3,2,0>,
              transform {rotate <0,35,0> translate <.3,0,0>},
              box {<-.07,-10,-10>,<.07,10,10> rotate <0,35,0> translate <-.3,0,0>}
              )
          }
      rotate <0,-20,0>
      translate <-6,0,0>
      }
  
  intersection {          // Demonstrating elliptical, or "Riemann", geometry
      box {<-2,0,-2>,<2,5,2>}
      sphere {<0,0,0>,2.8285}
      texture {
          SurfaceDrawing(<.65,2.45,1.25>,
              transform {rotate <0,5,0>  rotate <-45,35,0>},
              box {<-.07,-10,-10>,<.07,10,10> rotate <0,-4,0> rotate <-45,35,0>}
              )
          }
      rotate <0,-20,0>
      translate <0,0,0>
      }
  
  intersection {          // Demonstrating hyperbolic geometry
      box {<-2,0,-2>,<2,4,2>}
      torus {7.03,5 rotate <90,90,0> translate <0,4,0>}
      texture {
          SurfaceDrawing(<0,2.3,1>,
              transform {rotate <0,90,0> rotate <-40,0,0> translate <0,4,0>},
              merge {
                  box {<-.07,-10,-10>,<.07,10,10>
                      rotate <0,85,0> rotate <-30,0,0> translate <0,4,0>
                      }
                  box {<-.07,-10,-10>,<.07,10,10>
                      rotate <0,95,0> rotate <-30,0,0> translate <0,4,0>
                      }
                  }
              )
          }
      rotate <0,-20,0>
      translate <6,0,0>
      }
  
  camera {  // Viewpoint
      location <0,2100,-800>
      look_at <.5,0,0>
      angle .47
      }
  
  light_source {<-50,200,-100> color rgb 1.5} // Illumination

I, the copyright holder of this work, hereby publish it under the following licenses:
GNU head Licet hoc documentum exscribere vel distribuere vel demutare sub GNU Liberarum Litterarum Licentiae conditionibus in editione 1.2 aut in ulla editione recentiori a Fundatione Liberarum Programmationis Partium publicata; praeterquam Sectiones Immutabiles et Verba Involucra Adversa et Aversa. Licentiae exemplar praesto est in sectione intitulata GNU Free Documentation License.
w:en:Creative Commons
attributio aequa parte
This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
Tibi licet:
  • communicare – copiare, distribuere et committere hoc opus
  • to remix – to adapt the work
His condicionibus:
  • attributio – You must attribute the work in the manner specified by the author or licensor (but not in any way that suggests that they endorse you or your use of the work).
  • aequa parte – If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one.
This licensing tag was added to this file as part of the GFDL licensing update.
Tibi typum permissionis ligere licet.

Historia fasciculi

Presso die vel tempore fasciculum videbis, sicut tunc temporis apparuit.

Dies/TempusMinutioDimensionesUsorSententia
recentissima21:47, 5 Iulii 2015Minutum speculum redactionis 21:47, 5 Iulii 2015 factae4 000 × 1 500 (128 chiliocteti)CmdrjamesonCompressed with pngout. Reduced by 66kB (34% decrease).
19:13, 4 Augusti 2012Minutum speculum redactionis 19:13, 4 Augusti 2012 factae4 000 × 1 500 (194 chiliocteti)Mornredone at higher resolution
23:21, 7 Aprilis 2005Minutum speculum redactionis 23:21, 7 Aprilis 2005 factae790 × 310 (47 chiliocteti)Peo~commonswikiShows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate #euclidian #elliptical and #hyperbolic geometry Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped an

Ad hunc fasciculum nectunt:

Usus fasciculi per inceptus Vicimediorum

Metadata