#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid
set border 3               # Bit 1 (unten) + Bit 2 (links)


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'          # Beschr. X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange ['30.06.1699':'30.06.2006']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 25
                           #  xtics in Sekunden 
                           # der Beginn der X-Einteilung kann außerhalb xrange
                           # liegen
set xtics offset  0, 0.5   # Beschritung näher an die X-Achse
set mxtics 5               # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%Y'          # Beschriftungsformat JJJJ
set xtics  out             # Skal. aussen damit sich nicht von Grafik 
                           # überschr. wird


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label 
set yrange [0:]
set ytics 10000
set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f"      # Ausgabeformat
set mytics 5
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot \
  '-' using 1:2 with linespoints linecolor 'dark-blue'   linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30


#
# Quelle:
# https://de.wikipedia.org/wiki/M%C3%BClhausen#Einwohnerentwicklung
#
30.06.1699;3302
30.06.1798;5500
30.06.1800;6018
30.06.1806;8053
30.06.1821;9603
30.06.1831;13300
30.06.1836;16932
30.06.1841;20129
30.06.1846;29415
30.06.1851;29574
#	
30.06.1856;45981
30.06.1861;45587
30.06.1866;58773
30.06.1871;52892
30.06.1875;58513
30.06.1880;63629
30.06.1885;69759
30.06.1890;76892
30.06.1895;82986
30.06.1900;89118
#
30.06.1905;94498
30.06.1910;95041
30.06.1914;105000
30.06.1916;84835
30.06.1917;79543
30.06.1921;99226
30.06.1926;99892
30.06.1931;99534
30.06.1936;96697
30.06.1946;87655
#
30.06.1954;99079
30.06.1962;108995
30.06.1968;116336
30.06.1975;117013
30.06.1982;112157
30.06.1990;108357
30.06.1999;110359
30.06.2006;110514
EOF